# Licensed to the Apache Software Foundation (ASF) under one
# or more contributor license agreements.  See the NOTICE file
# distributed with this work for additional information
# regarding copyright ownership.  The ASF licenses this file
# to you under the Apache License, Version 2.0 (the
# "License"); you may not use this file except in compliance
# with the License.  You may obtain a copy of the License at
#
#   http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing,
# software distributed under the License is distributed on an
# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
# KIND, either express or implied.  See the License for the
# specific language governing permissions and limitations
# under the License.

# Justfile for example DAG bundle

# Default recipe to show help
default:
    @just --list

# Build the example bundle (raw go build, no footer; for Edge Worker testing)
build:
    @echo "Building example DAG bundle..."
    go build -o ../../bin/example-dag-bundle .

# Build with specific name and version (raw go build, no footer)
build-with name="data_processing_example" version="1.0.0":
    @echo "Building example DAG bundle with name={{name}} version={{version}}..."
    go build -ldflags="-X 'main.bundleName={{name}}' -X 'main.bundleVersion={{version}}'" -o ../../bin/{{name}}-{{version}} .

# One-step build + pack. The single `go tool airflow-go-pack`
# invocation runs `go build` internally, queries the binary for its
# DAG/task identity via --airflow-metadata, and appends the source plus
# airflow-metadata.yaml plus AFBNDL01 trailer. The output is a single
# self-contained executable bundle, named after the bundle's package
# directory and written to the current directory. Drop it into
# [executable] bundles_folder to deploy.
pack:
    @echo "Packing example DAG bundle..."
    go tool airflow-go-pack --output ../../bin/example_dags

# Pack with extra go build flags forwarded after "--".
pack-release:
    @echo "Packing example DAG bundle (release flags)..."
    go tool airflow-go-pack --output ../../bin/example_dags -- -trimpath -ldflags="-s -w"

# Inspect a packed bundle's embedded manifest.
inspect bundle="../../bin/example_dags":
    go tool airflow-go-pack inspect {{bundle}}
