/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */
package groovy

import org.junit.jupiter.api.Test

import static groovy.test.GroovyAssert.assertScript
import static groovy.test.GroovyAssert.shouldFail


class ConstructorMismatchTest {
    @Test
    void testConstructorMismatch() {
        def message = shouldFail(GroovyRuntimeException, '''
            class Event {
                Date when
                Event(Date when)  {
                    this.when = when
               }
            }
            new Event(42G)
        ''')
        assert message.message == 'Could not find matching constructor for: Event(BigInteger)'
    }

    @Test
    void testConstructorMismatchNamedArgs() {
        def message = shouldFail(GroovyRuntimeException, '''
            class Event {
                Date when
                Event(Date when)  {
                    this.when = when
               }
            }
            new Event(when: new Date())
        ''')
        assert message.message == 'Could not find named-arg compatible constructor. Expecting one of:\nEvent(Map)\nEvent()'
    }

    @Test
    void testMapConstructorThroughEMC() {
        assertScript'''
            class Person {
                String name
                Person(String name)  {
                    this.name = name
               }
            }

            Person.metaClass.constructor << { Map m -> new Person(m.name) }

            def j = new Person(name: 'John')
            assert j.name == 'John'
        '''
    }
}
