/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */
package groovy.toml

import org.junit.jupiter.api.Test

class TomlBuilderTest {

    @Test
    void testBuild() {
        // tag::build_text[]
        def builder = new TomlBuilder()
        builder.records {
            car {
                name 'HSV Maloo'
                make 'Holden'
                year 2006
                country 'Australia'
                homepage new URL('http://example.org')
                record {
                    type 'speed'
                    description 'production pickup truck with speed of 271kph'
                }
            }
        }

        assert builder.toString() == '''\
records.car.name = 'HSV Maloo'
records.car.make = 'Holden'
records.car.year = 2006
records.car.country = 'Australia'
records.car.homepage = 'http://example.org'
records.car.record.type = 'speed'
records.car.record.description = 'production pickup truck with speed of 271kph'
'''
        // end::build_text[]
    }

    // tag::typed_writing[]
    static class ServerConfig {
        String host
        int port
    }

    @Test
    void testToToml() {
        def config = new ServerConfig(host: 'localhost', port: 8080)
        def toml = TomlBuilder.toToml(config)
        assert toml.contains('host')
        assert toml.contains('localhost')
        assert toml.contains('port')
        assert toml.contains('8080')
    }
    // end::typed_writing[]

    @Test
    void testTypedRoundTrip() {
        def original = new ServerConfig(host: 'example.com', port: 443)
        def toml = TomlBuilder.toToml(original)
        def parsed = new TomlSlurper().parseTextAs(ServerConfig, toml)
        assert parsed.host == 'example.com'
        assert parsed.port == 443
    }
}