Matematiske funktioner

Dette afsnit indeholder de matematiske funktioner i Calc. For at åbne Funktionsguide, vælg Indsæt - Funktion.

AGGREGER

Denne funktion returnerer et aggregeret resultat af beregningen i området. Du kan benytte forskellige aggregeringsfunktioner som oplistet herunder. Aggreger-funktionen giver dig mulighed for at udelade skjulte rækker, fejl, subtotaler og andre AGGREGER-funktioner i beregningen.

RÅSUBTRAHER

Subtraherer et antal værdier og giver resultatet, uden at fjerne små afrundingsfejl.

FARVE

Returnerer en numerisk værdi beregnet af en kombination af tre farver (rød, grøn og blå) samt alfakanalen i RGBA-farvesystemet.Resultatet afhænger af farvesystemet som bruges på din computer.

SUM.FLERE.HVIS

Returnerer summen af værdier i celler i et område, der opfylder flere kriterier i flere områder.

RUND.NED (ROUNDDOWN på engelsk)

Afrunder et tal nedad mod nul med en angivet præcision.

Syntaks

RUND.NED(Tal; Antal)

Returnerer Tal nedrundet (mod nul) med Antal decimaler. Hvis Antal udelades eller er nul, runder funktionen ned til et heltal. Hvis Antal er negativ, runder funktionen ned til næste 10, 100, 1000 etc.

Denne funktion runder mod nul. Se RUND.OP og AFRUND for alternativer.

Eksempel

=RUND.NED(1,234; 2) returnerer 1,23.

=RUND.NED(45,67; 0) returnerer 45.

=RUND.NED(-45,67) returnerer -45.

=RUND.NED(987,65; -2) returnerer 900.

AFRUND (ROUND på engelsk)

Afrunder et tal til et bestemt antal decimaler.

Syntaks

AFRUND(Tal; Antal)

Returnerer Tal afrundet til Antal decimaler. Hvis Antal udelades eller er nul, afrunder funktionen til nærmeste heltal. Hvis Antal er negativ, afrunder funktionen til nærmeste 10, 100, 1000 etc.

Denne funktion afrunder til det nærmeste tal. Se RUND.NED og RUND.OP for alternativer.

Eksempel

=AFRUND(2,348; 2) returnerer 2,35

=AFRUND(-32,4834; 3) returnerer -32,483. Skift celleformatet for at se alle decimaler.

=AFRUND(2,348; 0) returnerer 2.

=AFRUND(2,5)returnerer 3.

=AFRUND(987,65; -2) returnerer 1000.

LOFT.XCL

Afrunder et tal væk fra nul til det nærmeste multiplum af Trin.

tip

Denne funktion er tilgængelig siden LibreOffice5.0


Syntaks

LOFT.XCL(Tal; Trin)

Tal er det tal, der skal afrundes.

Trin er værdien, som der skal rundes ned til et multiplum af.

warning

Denne funktion findes af hensyn til interoperabilitet med Microsoft Excel 2007 eller ældre versioner.


Eksempel

=LOFT.XCL(1;3) returnerer 3

=LOFT.XCL(7;4) returnerer 8

=LOFT.XCL(-10;-3) returnerer -12

AFKORT (TRUNC på engelsk)

Afskærer et tal ved at fjerne decimaler.

Syntaks

AFKORT(Tal; Antal)

Returnerer Tal med højst Antal decimaler. Yderligere decimaler fjernes blot uden hensyn til fortegn.

AFKORT(Tal; 0) opfører sig som HELTAL(Tal) for positive tal, men runder af mod nul for negative tal.

warning

Antallet af synlige decimaler i resultatet angives i - LibreOffice Calc - Beregn.


Eksempel

=AFKORT(1,239; 2) returnerer 1,23. 9 går tabt.

=AFKORT(-1,234999; 3) returnerer -1,234. Alle nitallerne går tabt.

SUBTOTAL

Beregner subtotaler. Hvis et område allerede indeholder subtotaler, vil disse ikke blive brugt til videre beregninger. Brug denne funktion sammen med Autofilter for kun at tage de filtrerede dataposter i betragtning.

Syntaks

SUBTOTAL(Funktion; Område)

Funktion er et tal, som står for en af de følgende funktioner:

Funktionsindeks

(inkluderer skjulte værdier)

Funktionsindeks

(ignorerer skjulte værdier)

Funktion

1

101

MIDDEL

2

102

TÆL

3

103

TÆLV

4

104

MAKS

5

105

MIN

6

106

PRODUKT (PRODUCT på engelsk)

7

107

STDAFV

8

108

STDAFVP

9

109

SUM

10

110

VARIANS

11

111

VARIANSP


Brug tallene 1-11 for at inkludere manuelt skjulte rækker eller 101-111 for at ekskludere dem; celler der er filtreret væk ekskluderes altid.

Område er området, hvis celler er inkluderede.

Eksempel

Du har en tabel i celleområdet A1:B6, der indeholder en regning på materialer til ti elever. Række 2 (Pen) er manuelt skjult. Du ønsker at se summen af de viste tal, dvs. kun subtotalen for de filtrerede rækker. I dette tilfælde vil den korrekte formel være:

A

B

1

VARE

ANTAL

2

Pen

10

3

Blyant

10

4

Notesblok

10

5

Viskelæder

10

6

Blyantspidser

10


=SUBTOTAL(9;B2:B6) returnerer 50.

=SUBTOTAL(109;B2:B6) returnerer 40.

PRODUKT (PRODUCT på engelsk)

Ganger alle tallene givet som argumenter og returnerer produktet.

Syntaks

PRODUKT(Tal1; Tal2; ...; Tal30)

Tal_1 til 30 er op til 30 argumenter, hvis produkt skal beregnes.

PRODUKT returnerer Tal1 * Tal2 * Tal3 * ...

Eksempel

=PRODUKT(2; 3; 4) returnerer 24.

SUMKV

Hvis du vil beregne kvadratsummen af nogle tal (summering af kvadraterne af argumenterne), kan du indtaste disse tal i tekstfelterne.

Syntaks

SUMKV(Tal1; Tal2; ...; Tal30)

Tal_1 til tal 30 er op til 30 argumenter, for hvilke kvadratsummen skal beregnes.

Eksempel

Hvis du indtaster tallene 2; 3 og 4 i tekstfelterne Tal_1;Tal_2 og Tal_3, vil 29 blive returneret som resultat.

KONVERTER_OOO

Konverterer en værdi fra en måleenhed til en anden måleenhed. Konverteringsfaktorerne findes i en liste i konfigurationen.

På et tidspunkt inkluderede listen af konverteringsfaktorer de traditionelle europæiske valutaer og Euroen (se eksemplet herunder). Vi foreslår at den ny funktion EUROKONVERTER bruges til at konverterer disse valutaer.

Syntaks

KONVERTER_OOO(værdi;"tekst";"tekst")

Eksempel

=KONVERTER_OOO(100;"ATS";"EUR") returnerer værdien i Euro af 100 Østrigske Schilling.

=KONVERTER_OOO(100;"EUR";"DEM") konverterer 100 Euro til D-mark.

EUROKONVERTER (EUROCONVERT på engelsk)

Konverterer gamle europæiske valutaer til og fra Euro.

Syntaks

EUROKONVERTER(Værdi; "Fra_valuta"; "Til_valuta", fuld_præcision, triangulær_præcision)

Værdi er beløbet i valutaenheden, som skal omregnes.

Fra_valuta og til_valuta er de valutaenheder, der skal konverteres fra henholdsvis til. De skal være tekst, den officielle forkortelse for den relevante valutaenhed (for eksempel, "EUR") som vist i tabellen nedenfor. Kurserne (vist pr. Euro) blev defineret af Den europæiske Kommission.

Fuld_præcision er valgfri. Hvis undladte eller Falsk, afrundes resultatet i henhold til decimaler i Til valuta. Hvis Fuld_præcision er Sand, afrundes resultatet ikke.

Triangulær_præcision er valgfri. Hvis Triangulær_præcision er givet og >=3, afrundes mellemresultatet af en triangulær konvertering (valuta1, EUR, valuta2) til denne præcision. Hvis Triangulær_præcision er udeladt, afrundes mellemresultatet ikke. Hvis Til valuta derudover er "EUR", så bruges Triangulær_præcision som hvis triangulation var nødvendig og konvertering fra EUR til EUR blev brugt.

Eksempler

=EUROKONVERTER(100;"DKK";"EUR") konverterer 100 danske kroner til Euro.

=EUROKONVERTER(100;"EUR";"DKK") konverterer 100 Euro til danske kroner.

RADIANER (RADIANS på engelsk)

Konverterer grader til radianer.

Syntaks

RADIANER(Tal)

Tal er vinklen i grader, som skal konverteres til radianer.

Eksempel

=RADIANER(90) returnerer 1,5707963267949, som er pi/2 med Calcs nøjagtighed.

SUM

Lægger alle tal i et celleområde sammen.

Syntaks

SUM(Tal_1; Tal_2; ...; Tal_30)

Tal1 til Tal30 er op til 30 argumenter, enten celler områder, hvis sum skal beregnes.

tip

SUM ignorerer al tekst eller tomme celler indenfor et område eller matrice. Hvis du har mistanke om forkerte resultater fra funktionen SUM, led efter tekst i dataområderne. Brug funktionaliteten Fremhæv værdier til at fremhæve det tekstindhold i området, som kan repræsentere et tal.


Eksempel

Hvis du indtaster tallene 2, 3 og 4 i tekstfelterne Tal_1, Tal_2 og Tal_3, vil resultatet 9 blive returneret.

=SUM(A1; A3; B5) beregner summen af de tre celler. =SUM (A1:E10) beregner summen af alle celler i celleområdet A1 til E10.

Betingelser sammenkædet med OG kan bruges med funktionen SUM() på følgende måde:

Eksempel: Du har indtastet fakturaer i en tabel. Kolonne A indeholder datoværdien af fakturaen, kolonne B indeholder beløbet. Du vil finde en formel, som du kan bruge til at beregne totalbeløbet for en specifik måned, for eksempel summen af fakturaer i perioden >=2008-01-01 til <2008-02-01. Området med datoværdierne dækker A1:A40. Området, som indeholder fakturabeløb, som skal opsummeres, er i B1:B40. C1 indeholder startdatoen, 2008-01-01, hvor fakturaer skal være inkluderet, og C2 datoen, 2008-02-01, som ikke længere skal inkluderes.

Indtast den følgende formel som en matrixformel:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

For at indtaste dette som en matrixformel, skal du trykke Skift+ Enter i stedet for bare at trykke på Enter for at lukke formlen. Formlen vil så blive vist i Formellinjen omgivet af klammeparenteser (tuborgklammer).

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Formlen er baseret på den kendsgerning, at resultatet af en sammenligning er 1, hvis kriteriet er opfyldt og 0, hvis det ikke er. Det enkelte sammenligningsresultat vil blive behandlet som en matrix og brugt i matrixmultiplikation, og til sidst vil de enkelte værdier blive lagt sammen og vist i en resulterende matrix.

SUM.HVIS

Lægger de celler sammen, som opfylder et bestemt kriterium. Denne funktion bruges til gennemse et område, når du søger efter en bestemt værdi.

Søgningen understøtter jokere eller regulære udtryk. Med regulære udtryk aktivere kan du indtaste "al.*", for eksempel for at finde det første sted med "al.*" fulgt af vilkårlige tegn. Hvis du vil søge efter en tekst, som også er et regulært udtryk, skal du også enten sætte en "\" foran hvert tegn eller lukke teksten inde i \Q...\E. Du kan slå den automatiske evaluering af jokere og regulære udtryk til og fra i- LibreOffice Calc - Beregn.

warning

Når du bruger funktioner, hvor et eller flere argumenter er strenge i søgekriterier, som repræsenter et regulært udtryk, er det første forsøg at konvertere kriteriestrenge til tal. For eksempel vil ",0" blive konverteret til 0,0 og så videre. Hvis det lykkes, vil matchet ikke være med et match med et regulært udtryk men et numerisk match. Når du skifter til en lokalisering, hvor decimaltegnet ikke er et punktum, virker konverteringen af det regulære udtryk i midlertid også. For at gennemtvinge evalueringen af det regulære udtryk i stedet for et numerisk udtryk, bruger du nogle udtryk, der ikke kan misforstås som numeriske, så som ".[0]", ".\0" eller "(?i).0".


Syntaks

SUM.HVIS(Område; Kriterier; Sum_område)

Område er området, som kriteriet skal anvendes på.

Kriterier er den celle, hvor kriteriet vises, eller kriteriet selv. Hvis kriteriet bliver skrevet ind i formlen, skal det omgives af dobbelt citationstegn (gåseøjne).

Sum_område er det område, hvori værdierne skal lægges sammen. Hvis denne parameter ikke er angivet, vil værdierne i Område blive lagt sammen.

note

SUM.HVIS understøtter kun operatoren til sammentrækning af henvisninger (~) i parameteren Kriterier, og kun hvis den valgfri parameter SumRange ikke er givet.


Eksempel

For kun at summere negative tal: =SUM.HVIS(A1:A10;"<0")

=SUM.HVIS(A1:A10;">0";B1:B10) - sammentæller kun værdier i området B1:B10, når de tilsvarende værdier i området A1:A10 er >0.

Se TÆL.HVIS() for flere eksempler på syntaks, der kan bruges med SUM.HVIS().

GRADER (DEGREES på engelsk)

Omregner radianer til grader.

Syntaks

GRADER(Tal)

Tal er vinklen i radianer, der skal konverteres til grader.

Eksempel

=GRADER(PI()) returnerer 180 grader.

STØRSTE.FÆLLES.DIVISOR_EXCEL2003

Resultatet er den største fælles divisor til en liste af tal.

note

De funktioner, hvis navne ender med _ADD eller EXCEL2003, returnerer de samme resultater som de tilsvarende Microsoft Excel 2003 funktioner uden endelse. Brug funktionerne uden endelse for at få resultater baseret på internationale standarder.


Syntaks

STØRSTE.FÆLLES.DIVISOR_EXCEL2003(Tal(s))

Tal er en liste af op til 30 tal.

Eksempel

=STØRSTE.FÆLLES.DIVISOR_EXCEL2003(5;15;25) returnerer 5.

MINDSTE.FÆLLES.MULTIPLUM_EXCEL2003

Resultatet er det mindste fælles multiplum af en liste af tal.

note

De funktioner, hvis navne ender med _ADD eller EXCEL2003, returnerer de samme resultater som de tilsvarende Microsoft Excel 2003 funktioner uden endelse. Brug funktionerne uden endelse for at få resultater baseret på internationale standarder.


Syntaks

MINDSTE.FÆLLES.MULTIPLUM_EXCEL2003(Tal(s))

Tal er en liste af op til 30 tal.

Eksempel

=MINDSTE.FÆLLES.MULTIPLUM_EXCEL2003(5;15;25) returnerer 75.

PI

Returnerer 3,14159265358979, værdien af den matematiske konstant Pi med 14 decimaler.

Syntaks

PI()

Eksempel

=PI() returnerer 3,14159265358979.

KOMBIN

Returnerer antallet af kombinationer for elementer uden gentagelse.

Syntaks

KOMBIN(Antal_1; Antal_2)

Antal_1 er antallet af elementer i mængden.

Antal_2 er antallet af elementer, der skal vælges fra mængden.

KOMBIN returnerer antal sorterede måder at vælge disse elementer. Hvis der for eksempel er 3 elementer, A, B og C i en mængde, kan du vælge 2 elementer på 3 forskellige måder, nemlig AB, AC og BC.

KOMBIN implementerer formlen: Antal_1!/(Antal_2!*(Antal_1-Antal_2)!)

Eksempel

=KOMBIN(3; 2) returnerer 3.

KOMBINA

Returnerer antallet af kombinationer for en delmængde af elementer inklusiv gentagelser.

Syntaks

KOMBINA(Antal_1; Antal_2)

Antal_1 er antallet af elementer i mængden.

Antal_2 er antallet af elementer, der skal vælges fra mængden.

KOMBINA returnerer antal måder, hvorpå disse elementer kan vælges, hvor rækkefølgen af udvælgelsen ikke er vigtig og hvor samme element gerne må bruges flere gange. Hvis der for eksempel er 3 elementer, A, B og C i en mængde, kan du vælge 2 elementer på 6 forskellige måder, nemlig AA, AB, AC, BB, BC og CC.

KOMBINA implementerer formlen: (Antal1+Antal2-1)! / (Antal2! (Antal1-1)!)

Eksempel

=KOMBINA(3; 2) returnerer 6.

ARCCOS (ACOS på engelsk)

Returnerer arccosinus af et tal.

Syntaks

ARCCOS(Tal)

Denne funktion returnerer den inverse trigonometriske cosinus til Tal, det vil sige den vinkel (i radianer), hvis cosinus er Tal. Den returnerede vinkel er mellem 0 og PI.

For at returnere vinklen i grader skal du bruge funktionen GRADER.

Eksempel

=ARCCOS(-1) returnerer 3,14159265358979 (pi radianer).

=GRADER((ARCCOS(0,5)) returnerer 60. Cosinus af 60 grader er 0,5.

ARCSIN (ASIN på engelsk)

Returnerer arcsinus af et tal.

Syntaks

ARCSIN (Tal)

Denne funktion returnerer den inverse trigonometriske sinus til Tal, det vil sige den vinkel (i radianer), hvis sinus er Tal. Den returnerede vinkel er mellem -PI/2 og +PI/2.

For at returnere vinklen i grader skal du bruge funktionen GRADER.

Eksempel

ARCSIN(0) returnerer 0.

ARCSIN(1) returnerer 1,5707963267949 (pi/2 radianer).

GRADER(ARCSIN(0,5)) returnerer 30. Sinus af 30 grader er 0,5.

ARCTAN (ATAN på engelsk)

Returnerer arctangens af et tal.

Syntaks

ARCTAN(Tal)

Denne funktion returnerer den inverse trigonometriske tangens af Tal, det vil sige den vinkel (i radianer), hvis tangens er Tal. Den returnerede vinkel er mellem -pi/2 og pi/2.

For at returnere vinklen i grader skal du bruge funktionen GRADER.

Eksempel

=ARCTAN(1) returnerer 0,785398163397448 (pi/4 radianer).

=GRADER(ARCTAN(1)) returnerer 45. Tangens af 45 grader er 1.

CSC

Returnerer cosekanten af en given vinkel (i radianer). Cosekanten af en vinkel er lig med 1 divideret med sinus af vinklen.

tip

Denne funktion er tilgængelig siden LibreOffice3.5


Syntaks

CSK(Tal)

Returnerer (den trigonometriske) cosekant til Tal, vinklen i radianer.

For at returnere cosekanten af en vinkel i grader, skal du bruge funktionen RADIANER.

Eksempel

=CSC(PI()/4) returnerer ca. 1,4142135624, hvilket er den inverse af sinus af PI/4 radianer.

=CSC(RADIANER(30)) returnerer 2, hvilket er cosekanten af 30 grader.

COS

Returnerer cosinus af den givne vinkel (i radianer).

Syntaks

COS(Tal)

Tal er den værdi, der skal beregnes cosinus af.

For at returnere cosinus af en vinkel i grader, skal du bruge funktionen RADIANER.

Eksempel

COS(PI()*2) returnerer 1, cosinus af 2*PI radianer.

COS(RADIANER(60)) returnerer 0,5, cosinus af 60 grader.

COT

Returnerer cotangens til den givne vinkel (i radianer).

Syntaks

COT(Tal)

Returnerer (den trigonometriske) cotangens af Tal, vinklen i radianer.

For at returnere cotangens af en vinkel i grader, skal du bruge funktionen RADIANER.

Cotangens af en vinkel svarer til 1 divideret med tangens til vinklen.

Eksempler:

COT(PI()/4) returnerer 1, cotangens af pi/4 radianer.

=COT(RADIANER(45)) returnerer 1, cotangens af 45 grader.

ABS

Returnerer den absolutte værdi af et tal.

Syntaks

ABS(Tal)

Tal er den værdi, hvis absolutte værdi skal beregnes. Den absolutte værdi af et tal er dets værdi uden +/- fortegnet.

Eksempel

=ABS(-56) returnerer 56.

=ABS(12) returnerer 12.

=ABS(0) returnerer 0.

CSCH

Returnerer den hyperbolske cosekant af et tal.

tip

Denne funktion er tilgængelig siden LibreOffice3.5


Syntaks

CSCH(Tal)

Returnerer den hyperbolske cosekant af Tal.

Eksempel

=CSCH(1) returnerer ca. 0.8509181282, den hyperbolske cosekant af 1.

COTH

Returnerer den hyperbolske cotangens af et givent Tal (Vinkel).

Syntaks

COTH(Tal)

Returnerer den hyperbolske cotangens af Tal.

Eksempel

=COTH(1) returnerer den hyperbolske cotangens af 1, tilnærmelsesvis 1,3130.

SEKH

Returnerer den hyperbolske sekant af et tal.

tip

Denne funktion er tilgængelig siden LibreOffice3.5


Syntaks

SEKH(Tal)

Returnerer den hyperbolske sekant af Tal.

Eksempel

=SEKH(0) returnerer 1, den hyperbolske sekant af 0.

ARCCOT (ACOT på engelsk)

Returnerer den inverse cotangens (arcus cotangens) for det givne tal.

Syntaks

ARCCOT(Tal)

Denne funktion returnerer den inverse trigonometriske cotangens til Tal, det vil sige den vinkel (i radianer), hvis cotangens er Tal. Den returnerede vinkel er mellem 0 og PI.

For at returnere vinklen i grader skal du bruge funktionen GRADER.

Eksempel

=ARCCOT(1) returnerer 0,785398163397448 (pi/4 radianer).

=GRADER(ARCCOT(1 )) returnerer 45. Tangens af 45 grader er 1.

ARCCOTH (ACOTH på engelsk)

Returnerer den inverse hyperbolske cotangens for det givne tal.

Syntaks

ARCCOTH(Tal)

Denne funktion returnerer den inverse hyperbolske cotangens til Tal, det vil sige det tal, hvis hyperbolske cotangens er Tal.

Der fremkommer en fejl, hvis Tal er mellem -1 og 1 inklusiv.

Eksempel

=ARCCOTH(1,1) returnerer den inverse hyperbolske cotangens af 1,1, tilnærmelsesvis 1,52226.

LN

Returnerer den naturlige logaritme til et tal baseret på konstanten e. Værdien af e er ca. 2,71828182845904.

Syntaks

LN(Tal)

Tal er den værdi, hvis naturlige logaritme skal beregnes.

Eksempel

=LN(3) returnerer den naturlige logaritme af 3 (omtrent 1,0986).

=LN(EKSP(321)) returnerer 321.

KVROD (SQRT på engelsk)

Returnerer den positive kvadratrod af et tal.

Syntaks

KVROD(Tal)

Returnerer den positive kvadratrod af Tal.

Tal skal være positiv.

Eksempel

=KVROD(16) returnerer 4.

=KVROD(-16) returnerer fejlen ugyldigt argument.

STØRSTE.FÆLLES.DIVISOR (GCD på engelsk)

Returnerer den største fælles divisor til to eller flere heltal.

Den største fælles divisor er det største positive heltal, som kan dele hvert af de givne heltal uden rest.

Syntaks

STØRSTE.FÆLLES.DIVISOR(Heltal_1; Heltal_2; ...; Heltal_30)

Heltal_1 til 30 er op til 30 heltal, hvis største fælles divisor skal beregnes.

Eksempel

=STØRSTE.FÆLLES.DIVISOR(16;32;24) giver resultatet 8, fordi 8 er det største tal, som går op i 16, 24 og 32 uden at give en rest.

=STØRSTE.FÆLLES.DIVISOR(B1:B3) hvor cellerne B1, B2, B3 indeholde 9, 12, 9 giver 3.

MINDSTE.FÆLLES.MULTIPLUM (LCM på engelsk)

Returnerer det mindste fælles multiplum af ét eller flere heltal.

Syntaks

MINDSTE.FÆLLES.MULTIPLUM(Heltal_1; Heltal_2; ...; Heltal_30)

Heltal_1 til 30 er op til 30 heltal, hvis mindste fælles multiplum skal beregnes.

Eksempel

Hvis du indtaster tallene 512; 1024 og 2000 i tekstfelterne Heltal_1; 2 og 3, bliver resultatet 128000 returneret.

EKSP (EXP på engelsk)

Returnerer e opløftet i en potens. Konstanten e har en tilnærmet værdi på 2,71828182845904.

Syntaks

EKSP(Tal)

Tal er potensen som e skal opløftes til.

Eksempel

=EKSP(1) returnerer 2,71828182845904, den matematiske konstant e med Calcs præcision.

MAFRUND (MROUND på engelsk)

Returnerer et tal afrundet til det nærmeste multiplum af et andet tal.

Syntaks

MAFRUND(Værdi; Multiplum)

Returnerer Værdi afrundet til det nærmeste multiplum af Multiplum.

En alternativ implementering ville være Multiplum * ROUND(Værdi/Multiplum).

Eksempel

=MAFRUND(15,5; 3) returnerer 15, da 15,5 er nærmere 15 (= 3*5) end 18 (= 3*6).

=MAFRUND(1,4; 0,5) returns 1,5 (= 0,5*3).

COSH

Returnerer et tals hyperbolske cosinus.

Syntaks

COSH(Tal)

Returnerer den hyperbolske cosinus af Tal.

Eksempel

COSH(0) returnerer 1, den hyperbolske cosinus af 0.

SINH

Returnerer et tals hyperbolske sinus.

Syntaks

SINH(Tal)

Returnerer den hyperbolske sinus af Tal.

Eksempel

=SINH(0) returnerer 0, den hyperbolske sinus af 0.

TANH

Returnerer et tals hyperbolske tangens.

Syntaks

TANH(Tal)

Returnerer den hyperbolske tangens af Tal.

Eksempel

=TANH(0) returnerer 0, den hyperbolske tangens af 0.

ARCCOSH (ACOSH på engelsk)

Returnerer et tals inverse hyperbolske cosinus.

Syntaks

ARCCOSH(Tal)

Denne funktion returnerer den inverse hyperbolske cosinus til Tal, det vil sige den værdi, hvis hyperbolske cosinus er Tal.

Tal skal være større end eller lig med 1.

Eksempel

=ARCCOSH(1) returnerer 0.

=ARCCOSH(COSH(4)) returnerer 4.

ARCSINH (ASINH på engelsk)

Returnerer et tals inverse hyperbolske sinus.

Syntaks

ARCSINH(Tal)

Denne funktion returnerer den inverse hyperbolske sinus til Tal, det vil sige det tal, hvis hyperbolske sinus er Tal.

Eksempel

=ARCSINH(-90) returnerer ca. -5,1929877.

=ARCSINH(SINH(4)) returnerer 4.

ARCTANH (ATANH på engelsk)

Returnerer et tals inverse hyperbolske tangens.

Syntaks

ARCTANH(Tal)

Denne funktion returnerer den inverse hyperbolske tangens af Tal, det vil sige den værdi, hvis hyperbolske tangens er Tal.

Tal skal opfylde betingelsen -1 < Tal < 1.

Eksempel

ARCTANH(0) returnerer 0.=ATANH(0)

SLUMPMELLEM (RANDBETWEEN på engelsk)

Returnerer et tilfældigt heltal tilfældig i et angivet område.

Syntaks

SLUMPMELLEM (Bund; Top)

Returnerer et tilfældigt heltal mellem heltallene Bund og Top (begge inklusive).

Denne funktion danner et nyt tilfældigt tal hver gang Calc genberegner. Tving Calc til at genberegne ved at trykke på F9.

For at generere tilfældige tal, som aldrig bliver genberegnet, skal du kopiere celler, der indeholder denne funktion, og bruge Rediger - Indsæt Speciel (med Indsæt alt og ikke Formler markeret og Tal markeret).

Eksempel

=SLUMPMELLEM (20;30) returnerer et heltal på mellem 20 og 30.

SLUMP (RAND på engelsk)

Returnerer et tilfældigt tal mellem 0 og 1.

Syntaks

SLUMP( )

Denne funktion danner et nyt tilfældigt tal hver gang Calc genberegner. For at tvinge Calc til at genberegne kan du trykke på F9.

For at generere tilfældige tal, der aldrig genberegnes, skal du kopiere celler, der hver indeholder =SLUMP() og bruge Rediger - Indsæt speciel (med Indsæt alt og Formler umarkeret og Tal markeret).

Eksempel

=SLUMP() returnerer et tilfældigt tal mellem 0 og 1.

FAKULTET (FACT på engelsk)

Returnerer fakulteten af et tal.

Syntaks

FAKULTET(Tal)

Returnerer Tal!, fakulteten af Tal, beregnet som 1*2*3*4 ... * Tal.

=FAKULTET(0) returnerer per definition 1.

Fakulteten af et negativt tal returnerer fejlen "ugyldigt argument".

Eksempel

=FAKULTET(3) returnerer 6.

=FAKULTET(0) returnerer 1.

MULTINOMIAL

Returnerer fakultetet af summen af argumenterne divideret med produktet af fakultetet af argumenterne.

Syntaks

MULTINOMIAL(Tal)

Tal er en liste af op til 30 tal.

Eksempel

=MULTINOMIAL(F11:H11) returnerer 1260, hvis F11 til H11 indeholder værdierne 2, 3 og 4. Dette svarer til formlen =(2+3+4)! / (2!*3!*4!)

FORTEGN (SIGN på engelsk)

Returnerer fortegnet af et tal. Returnerer 1, hvis tallet er positivt, -1 hvis det er negativt, og 0 hvis det er nul.

Syntaks

FORTEGN(Tal)

Tal er tallet hvis fortegn skal findes.

Eksempel

=FORTEGN(3,4) returnerer 1.

=FORTEGN(-4,5) returnerer -1.

KVOTIENT (QUOTIENT på engelsk)

Returnerer heltalsresultatet af en division.

Syntaks

KVOTIENT(Tæller; Nævner)

Returnerer heltalsdelen af Tæller divideret med Nævner.

KVOTIENT svarer til HELTAL(tæller/nævner) for tæller og nævner med samme fortegn, bortset fra, at det kan returnere fejl med forskellige fejlkoder. Mere generelt svarer det til HELTAL(tæller/nævner/FORTEGN(tæller/nævner))*FORTEGN(tæller/nævner).

Eksempel

=KVOTIENT(11; 3) returnerer 3. Resten på 2 går tabt.

KVRODPI (SQRTPI på engelsk)

Returnerer kvadratroden af (pi gange et tal).

Syntaks

KVRODPI (Tal)

Returnerer den positive kvadratrod af (PI ganget med Tal).

Dette er det samme som KVROD(PI()*Tal).

Eksempel

=KVRODPI(2) returnerer kvadratroden af (2pi), omtrent 2,506628.

LOG

Returnerer logaritmen af et tal med det angivne grundtal.

Syntaks

LOG(Tal; Grundtal)

Tal er den værdi, hvis logaritme skal beregnes.

Grundtal er grundtallet for logaritmen. Hvis udeladt benyttes grundtal 10.

Eksempel

=LOG(10; 3) returnerer tretalslogaritmen af 10 (cirka 2,0959).

=LOG(7^4; 7) returnerer 4.

REST (MOD på engelsk)

Returnerer resten ved division af et heltal med et andet.

Syntaks

REST(Tæller; Nævner)

For heltallige argumenter returnerer denne funktion Tæller rest Nævner, det vil sige resten, når Tæller divideres med Nævner.

Denne funktion er implementeret som Tæller - Nævner * HELTAL(Tæller/Nævner), og denne formel giver resultatet, hvis argumenterne ikke er et heltal.

Eksempel

=REST(22; 3) returnerer 1, resten når 22 divideres med 3.

=REST(11,25; 2,5) returnerer 1,25.

POTENS (POWER på engelsk)

Returnerer resultatet af en potensopløftning.

Syntaks

POTENS(Grundtal; Eksponent)

Returnerer Grundtal opløftet til eksponenten Eksponent.

Det samme resultat kan opnås ved at bruge exponentoperatoren ^:

Grundtal^Eksponent

Eksempel

POTENS(4; 3) returnerer 64, hvilket er 4 opløftet i 3. potens.

4^3 returnerer også 4 opløftet i 3. potens.

SEK

Returnerer sekanten af en given vinkel (i radianer). Sekanten af en vinkel svarer til 1 divideret med cosinus til vinklen.

tip

Denne funktion er tilgængelig siden LibreOffice3.5


Syntaks

SEK(Tal)

Returnerer (den trigonometriske) sekant af Tal, vinklen i radianer.

For at returnere sekanten af en vinkel i grader skal du bruge funktionen RADIANER.

Eksempel

=SEK(PI()/4) returnerer ca. 1.4142135624, hvilket er den inverse af cosinus af PI/4 radianer.

=SEK(RADIANER(60)) returnerer 2, sekanten af 60 grader.

SIN

Returnerer sinus af den givne vinkel (i radianer).

Syntaks

SIN(Tal)

Returnerer (den trigonometriske) sinus af Tal, vinklen i radianer.

For at returnere sinus af en vinkel i grader skal du bruge funktionen RADIANER.

Eksempel

=SIN(PI()/2) returnerer 1, sinus til pi/2 radianer.

=SIN(RADIANER(30)) returnerer 0,5, sinus af 30 grader.

TAN

Returnerer tangens til den givne vinkel (i radianer).

Syntaks

TAN(Tal)

Returnerer (den trigonometriske) tangens af Tal, vinklen i radianer.

For at returnere tangens af en vinkel i grader skal du bruge funktionen RADIANER.

Eksempel

=TAN(PI()/4) returnerer 1, tangens af pi/4 radianer.

=TAN(RADIANER(45)) returnerer 1, tangens til 45 grader.

LOG10

Returnerer titalslogaritmen af et tal.

Syntaks

LOG10(Tal)

Returnerer titalslogaritmen af Tal.

Eksempel

=LOG10(5) returnerer titalslogaritmen af 5 (cirka 0,69897).

ARCTAN2

Returnerer vinklen (i radianer) mellem x-aksen og en linje fra 0-punktet til dette punkt (NumberX|NumberY).

Noteikon

Denne funktion er en del af Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)


Syntaks

ARCTAN2(Tal_X; Tal_Y)

Tal_X er værdien af x-koordinaten.

Tal_Y er værdien af y-koordinaten.

tip

Programmeringssprog har normalt den modsatte rækkefølge argumenter i deres atan2()-funktion.


ATAN2 returnerer vinklen (i radianer) mellem x-aksen og en linje fra 0-punktet til dette punkt (NumberX|NumberY)

Eksempel

ATAN2(-5;9) returnerer 2,07789 radianer.

For at få vinklen i grader bruger du GRADER-funktionen på resultatet.

=GRADER(ATAN2(12.3;12.3)) returnerer 45. Tangenten til 45 grader er 1.

note

LibreOffice svarer 0 for ATAN2(0;0).


Funktionen kan bruges til at konvertere cartesiske koordinater til polare koordinater.

=GRADER(ATAN2(-8;5)) returns φ = 147,9 grader

Eksempel på kartesiske koordinater til polare koordinater

LIGE (EVEN på engelsk)

Runder et positivt tal op til nærmeste lige heltal og et negativt tal ned til nærmeste lige heltal.

Syntaks

LIGE(Tal)

Returnerer Tal rundet op til det nærmeste heltal, væk fra nul.

Eksempel

=Lige(2,3) returnerer 4.

=Lige(2) returnerer 2.

=Lige(0) returnerer 2.

=Lige(-0,5) returnerer -2.

ULIGE (ODD på engelsk)

Runder et positivt tal op til nærmeste ulige heltal og et negativt tal ned til nærmeste ulige heltal.

Syntaks

ULIGE(Tal)

Returnerer Tal rundet op til næste ulige heltal, væk fra nul.

Eksempel

=ULIGE(1,2) returnerer 3.

=ULIGE(1) returnerer 1.

=ULIGE(0) returnerer 1.

=ULIGE(-3,1) returnerer -5.

GULV.PRÆCIS

Runder et tal ned til det nærmeste multiplum af trin, uanset fortegnet på dette

tip

Denne funktion er tilgængelig siden LibreOffice4.3


Syntaks

GULV.PRÆCIS(Tal; Nøjagtighed)

Tal er det tal, der skal rundes ned.

Nøjagtighed er værdien, der skal rundes ned til et multiplum af.

warning

Hvis regnearket eksporteres til Microsoft Excel, eksporteres funktionen AFRUND.GULV som den tilsvarende funktion GULV.MAT som har eksisteret siden Excel 2013. Hvis du har planer om at anvende regnearket med tidligere versioner, skal du i stedet anvende funktionen GULV.PRÆCIS som har eksisteret siden Excel 2010, eler GULV.XCL som eksporteres som AFRUND.GULV kompatibel med alle versioner af Excel. Bemærk at GULV.XCL altid afrunder nedad mod nul.


Eksempel

=GULV.PRÆCIS( -11;-2) returnerer -12

HELTAL (INT på engelsk)

Runder et tal ned til nærmeste heltal.

Syntaks

HELTAL(Tal)

Returnerer Tal rundet ned til det nærmeste heltal.

Negative tal rundes ned til heltallet under.

Eksempel

=HELTAL(5,7) returnerer 5.

=HELTAL(-1,3) returnerer -2.

AFRUND.GULV (FLOOR på engelsk)

Runder et tal ned til nærmeste multiplum af Trin.

Syntaks

AFRUND.GULV(Tal; Trin; Tilstand)

Tal er det tal, der skal rundes ned.

Nøjagtighed er værdien, der skal rundes ned til et multiplum af.

Tilstand er en valgfri værdi. Hvis den er angivet og er forskellig fra nul, og hvis Tal og Trin er negative, vil afrunding blive udført baseret på den numeriske værdi af Tal, dvs. negative tal afrundes mod nul. Hvis værdien Tilstand er lig med nul eller ikke er givet, bliver negative tal afrundet væk fra nul.

warning

Hvis regnearket eksporteres til Microsoft Excel, eksporteres funktionen AFRUND.GULV som den tilsvarende funktion GULV.MAT som har eksisteret siden Excel 2013. Hvis du har planer om at anvende regnearket med tidligere versioner, skal du i stedet anvende funktionen GULV.PRÆCIS som har eksisteret siden Excel 2010, eler GULV.XCL som eksporteres som AFRUND.GULV kompatibel med alle versioner af Excel. Bemærk at GULV.XCL altid afrunder nedad mod nul.


Eksempel

=AFRUND.GULV( -11;-2) returnerer -12

=AFRUND.GULV( -11;-2;0) returnerer -12

=AFRUND.GULV( -11;-2;1) returnerer -10

AFRUND.LOFT (CEILING på engelsk)

Runder et tal op til det nærmeste multiplum af en angivet nøjagtighed.

Syntaks

AFRUND.LOFT(Tal; Trin; Tilstand)

Tal er det tal, der skal rundes op.

Trin er det tal, som resultatet skal være et multiplum af.

Tilstand er en valgfri værdi. Hvis værdien Tilstand er givet og ikke er nul, og hvis Tal og Signifikans er negative, da vil afrunding ske baseret på den absolutte værdi af Tal. F.eks. er negative tal afrundet væk fra nul. Hvis værdien Tilstand er nul eller ikke angivet, afrundes negative tal imod nul.

warning

Hvis regnearket eksporteres til Microsoft Excel, vil LOFT-funktionen blive eksporteret til den tilsvarende LOFT.MATEMATIK-funktion som har eksisteret siden Excel 2013. Hvis du planlægger at anvende regnearket med tidligere versioner af Excel, skal du bruge enten LOFT.PRÆCIS som har eksisteret siden Excel 2010 eller LOFT.XCL som eksporteres som LOFT-funktionen som er kompatibel med alle versioner af Excel. Bemærk at LOFT.XCL altid afrunder væk fra nul.


Eksempel

=AFRUND.LOFT( -11; -2) returnerer -10

=AFRUND.LOFT( -11; -2; 0) returnerer -10

=AFRUND.LOFT( -11; -2; 1) returnerer -12

LOFT.MATEMATIK

Runder et tal op til det nærmeste multiplum af en angivet nøjagtighed.

Syntaks

LOFT.MATEMATIK(Tal; Trin; Tilstand)

Tal er det tal, der skal rundes op.

Trin er det tal, som resultatet skal rundes op til være et multiplum af.

Tilstand er en valgfri værdi. Hvis værdien Tilstand er givet og ikke er nul, og hvis Tal og Signifikans er negative, da vil afrunding ske baseret på den absolutte værdi af Tal. F.eks. er negative tal afrundet væk fra nul. Hvis værdien Tilstand er nul eller ikke angivet, afrundes negative tal imod nul.

warning

Denne funktion findes af hensyn til interoperabilitet med Microsoft Excel 2013 eller nyere.


Eksempel

=LOFT.MATEMATIK(-10;-3) returnerer -9

=LOFT.MATEMATIK(-10;-3;0) returnerer -9

=LOFT.MATEMATIK(-10;-3;1) returnerer -12

LOFT.PRÆCIS

Runder et tal op til det nærmeste multiplum af nøjagtighed, uanset tegnet for nøjagtigheden

tip

Denne funktion er tilgængelig siden LibreOffice4.3


Syntaks

LOFT.PRÆCIS(Tal; Nøjagtighed)

Tal (krævet) er det tal, der skal rundes op.

Trin (valgfri) er det tal, hvis multiplum værdien skal rundes op til.

Eksempel

=LOFT.PRÆCIS( -11; -2) returnerer -10

ISO.LOFT

Runder et tal op til det nærmeste multiplum af trin, uanset fortegnet på dette

Syntaks

ISO.LOFT(Tal; Nøjagtighed)

Tal (krævet) er det tal, der skal rundes op.

Trin (valgfri) er det tal, hvis multiplum værdien skal rundes op til.

Eksempel

=ISO.LOFT(-11;-2) returnerer -10

RUND.OP (ROUNDUP på engelsk)

Runder et tal op, væk fra nul, i henhold til den angivne præcision.

Syntaks

RUND.OP(Tal; Antal)

Returnerer Tal rundet op (væk fra nul) med Antal decimaler. Hvis Antal udelades eller er nul, runder funktionen op til et heltal. Hvis Antal er negativ, runder funktionen op til næste 10, 100, 1000 etc.

Denne funktion runder væk fra nul. Se RUND.NED og AFRUND for alternativer.

Eksempel

=RUND.OP(1,1111; 2) returnerer 1,12.

=RUND.OP(1,2345; 1) returnerer 1,3.

=RUND.OP(45,67; 0) returnerer 46.

=RUND.OP(-45.67) returnerer -46.

=RUND.OP(987,65; -2) returnerer 1000.

SERIESUM

Summerer de første elementer af en potensrække.

SERIESUM(X;N;m;Koefficienter) = koefficient_1*X^N + koefficient_2*X^(N+m) + koefficient_3*X^(N+2m) +...+ koefficient_i*X^(N+(i-1)m)

Syntaks

SERIESUM(X; N; M; Koefficienter)

X er inputværdien for potensrækken

N er startpotensen

M er forøgelsen af N

Koefficienter er en række af koefficienter. For hver koefficient bliver rækkens sum udvidet med et led.